Content Controls (Structured Document Tags)

Imports GemBox.Document
Imports GemBox.Document.CustomMarkups

Module Program

    Sub Main()

        ' If using Professional version, put your serial key below.
        ComponentInfo.SetLicense("FREE-LIMITED-KEY")

        Dim document As New DocumentModel()

        Dim section As New Section(document)
        document.Sections.Add(section)

        ' Create locked Rich Text Content Control.
        Dim richTextControl As New BlockContentControl(document, ContentControlType.RichText,
            New Paragraph(document, "This text is inside Rich Text Content Control."),
            New Paragraph(document, "It cannot be deleted or edited."))
        richTextControl.Properties.LockEditing = True
        richTextControl.Properties.LockDeleting = True
        section.Blocks.Add(richTextControl)

        ' Create named Plain Text Content Control.
        Dim plainTextControl As New BlockContentControl(document, ContentControlType.PlainText,
            New Paragraph(document, "Plain Text Content Control with tag and title."))
        plainTextControl.Properties.Tag = "Plain Text Name"
        plainTextControl.Properties.Title = "Plain Text Title"
        section.Blocks.Add(plainTextControl)

        ' Create CheckBox Content Control.
        Dim checkBoxControl As New InlineContentControl(document, ContentControlType.CheckBox,
           New Run(document, "☒") With {.CharacterFormat = New CharacterFormat() With {.FontName = "MS Gothic"}})
        checkBoxControl.Properties.Checked = True

        ' Create ComboBox Content Control.
        Dim comboBoxControl As New InlineContentControl(document, ContentControlType.ComboBox,
            New Run(document, "<Select GemBox Component>"))
        comboBoxControl.Properties.ListItems.Add(New ContentControlListItem("<Select GemBox Component>", "NONE"))
        comboBoxControl.Properties.ListItems.Add(New ContentControlListItem("GemBox.Spreadsheet", "GBS"))
        comboBoxControl.Properties.ListItems.Add(New ContentControlListItem("GemBox.Document", "GBD"))
        comboBoxControl.Properties.ListItems.Add(New ContentControlListItem("GemBox.Pdf", "GBA"))
        comboBoxControl.Properties.ListItems.Add(New ContentControlListItem("GemBox.Presentation", "GBP"))
        comboBoxControl.Properties.ListItems.Add(New ContentControlListItem("GemBox.Email", "GBE"))

        section.Blocks.Add(New Paragraph(document,
            checkBoxControl,
            New SpecialCharacter(document, SpecialCharacterType.LineBreak),
            comboBoxControl))

        document.Save("Content Controls.docx")

    End Sub
End Module

Imports System.IO
Imports System.Xml
Imports System.Linq
Imports System.Text.RegularExpressions
Imports GemBox.Document
Imports GemBox.Document.CustomMarkups

Module Program

    Sub Main()

        ' If using Professional version, put your serial key below.
        ComponentInfo.SetLicense("FREE-LIMITED-KEY")

        Dim document = DocumentModel.Load("%#XmlMapping.docx%")

        ' Get the Content Control.
        Dim contentControl = CType(document.GetChildElements(True, ElementType.InlineContentControl).First(), InlineContentControl)
        Dim xmlMapping = contentControl.Properties.XmlMapping

        ' Get the mapped XML part.
        Dim xmlPart = xmlMapping.CustomXmlPart

        ' Create XmlDocument from XML.
        Dim xmlDocument = new XmlDocument()
        xmlDocument.Load(new MemoryStream(xmlPart.Data))

        ' Create a namespace manager.
        Dim namespaceManager = New XmlNamespaceManager(xmlDocument.NameTable)

        ' If XmlMapping specifies prefixes, parse them and fill the namespace manager.
        If Not String.IsNullOrEmpty(xmlMapping.PrefixMappings) Then
            Dim regex = New Regex("xmlns:(?<prefix>[\\S]+)='(?<namespace>[\\S]+)'")
            For Each match As Match In regex.Matches(xmlMapping.PrefixMappings)
                namespaceManager.AddNamespace(match.Groups("prefix").Value, match.Groups("namespace").Value)
            Next
        End If

        ' Locate the node to which is the Content Control mapped using XPath.
        Dim node = xmlDocument.SelectSingleNode(xmlMapping.XPath, namespaceManager)

        ' Change the node value.
        node.InnerText = "%NewFirstName%"

        ' Update the XmlPart Data.
        Dim outputMemoryStream = new MemoryStream()
        xmlDocument.Save(outputMemoryStream)
        xmlPart.Data = outputMemoryStream.ToArray()

        ' Get the node value.
        Dim nodeValue = node.InnerText

        ' Update Content Control inlines.
        contentControl.Inlines.Clear()
        contentControl.Inlines.Add(New Run(document, nodeValue) With
        {
            .CharacterFormat = contentControl.Properties.CharacterFormat
        })

        document.Save("Xml Mapping.%OutputFileType%")

    End Sub
End Module